In the Old Cathedral, the saintess raises a chalice at the altar as the congregation weeps for the Hero of Sienan. What is the name gracing their lips?
*input_text fname
*set nameset true

In a small town in the Parami east, the innkeep's lips tremble as she plants flowers around a pair of graves. Whose names are etched onto the headstones?
*choice
    #The innkeep's two sons.
        *set they "he"
        *set their "his"
        *set them "him"
        *set themselves "himself"
        *set theirs "his"
        *set pronvar 1
        *set plural false
        *set gender "male"
    #A daughter, and a son.
        *set they "she"
        *set their "her"
        *set them "her"
        *set themselves "herself"
        *set theirs "hers"
        *set pronvar 2
        *set plural false
        *set gender "female"
    #A son, and someone who eschewed such labels.
        *set they "they"
        *set their "their"
        *set them "them"
        *set themselves "themselves"
        *set theirs "theirs"
        *set pronvar 3
        *set plural true
        *set gender "nonbinary"

*set genderset true
*page_break
The stage is set, and the pyre lit. This is the story of mourners, the ones who were left behind.
*page_break

The war was hard on them all.

Leon was first to show the signs. They had taken to calling him the Sun Prince, their tone reverent as if he were Jove reborn. He would play the part dutifully, level his blade as if it were made from paper, charge with the conviction of a victor. At the battles' end he would cut a gallant figure against the light of the setting sun, and every time she finds that she is nearly convinced by the myth.

But after the castles are claimed and the trumpets sounded, he would return to his quarters even before the first of the mead is doled out. Saine had learned quickly to play ambassador to the camp, and the excuses roll off his tongue with expert ease. There are battle plans to be drawn, he would say, diplomats to greet. But his brother sends his regards, wants them all to know that this was a victory well-won—that they should drink his share in his honor. The soldiers would answer with a raucous cheer, cheeks flushed from the high of their triumph, and forget all which does not sit in their mugs.

She makes the cursory visit to Leon's chambers each night, where he hangs his head like a man defeated. He would down the tonics wordlessly, refuse her offers of healing even as he winces from the phantom pains pervading his bones. She would take offense, were it not for the way that his every movement spoke of a mild, weary gratitude. She knows that it is all he could muster, these days, when each victory paints a new crease into the planes of his face.

Some days ${fname} and Saine would come with her, if only to remind each other of happier, peaceful times. And in those nights where there were none to behold him but his most trusted, Leon would look remarkably like a prince in eclipse.

*choice
    #${fname} was much the same way.
        $!{they} would @{plural come|comes}
        into the room in silence, shoulders slumped from the weight of ${their} station. She could not find it in herself to blame ${them}. She knows that ${theirs} is a mighty burden, mightier still than any one person ought to bear—and yet ${they} @{plural bear|bears} it all without complaint.
        
        She would remember those sessions by the hearth of Leon's chamber as the war's true battlefield. Here were the Sun Prince and the mage that gave spirit to his resistance, rings thick as callouses around their eyes and nerves a hair's breadth from breaking. Saine was ever the valiant vanguard, brandishing good cheer and trivial tales as a soldier would his blade—and she followed his lead.
        
        (Her heart was never in it, but she was a born noble and a saintess-to-be besides. Artifice and pleasantries came as easily to her as breathing, and for all that Leon and ${fname} knew better than to put stock in the fiction, they were kind enough to play along.)
    #${fname}, meanwhile, was the picture of strength and professionalism.
        She does not know how ${they} @{plural manage|manages} it. Here was the mage upon whose back the resistance is built, who withers daily under the strain of
        ${their} great and terrible power. Every battle would see ${them} laid bare on the doors of death, and each time they would pull ${them} back out—and ask ${them} to die for them once more.
        
        And yet without fail, by nightfall ${they} will have pieced together all ${their} fragments, slather on a mask of perfect composure. $!{they} would speak of victory the way one speaks of daybreak—tendrils of light already unfurling on the horizon, certain as gravity. Sounding so sure of @{pronvar himself|herself|themselves}
        that they do not prod for proof.
        
        (She does not miss the way ${their} parables take the tension from Leon's shoulders and stoke the fire in his eyes. The prince beheld ${them} as if [i]${they}[/i] were the sun, and privately she wonders if anything in the sky ever did blaze as brilliantly as ${they}.)
    #${fname}, meanwhile, looked as if ${they} @{plural were|was} in ${their} element.
        She envies and fears it by turns, ${their} battle fervor. $!{they} @{plural wield|wields}
        each spell as if it might be ${their} last, powers through the searing consequence of ${their} terrible gift without so much as a wince. Every battle they ask ${them} to die, so that Param might live. $!{they} would square ${their} shoulders and meet the request with a grin, violent mana rippling through the air around ${them}.
        Against all odds, ${they} would come back from the edge without fail, the next day ready to die once more.
        
        It does not surprise her when ${they} @{plural walk|walks}
        into Leon's chambers with the kind of easy stride that belonged to peacetime. There by the hearth of Leon's chamber, ${they} would speak of victory the way one speaks of daybreak—tendrils of light already unfurling on the horizon, certain as gravity. Sounding so sure of @{pronvar himself|herself|themselves}
        that they do not prod for proof.
        
        (She does not miss the way ${their} parables take the tension from Leon's shoulders and stoke the fire in his eyes. The prince looked at ${them} as if [i]${they}[/i] were the sun; privately she would find the comparison apt, for ${fname} blazed so brilliantly that she found ${them} difficult to behold.)
*page_break
The best day for her came late into the war, when the resistance began closing in on Calinger. They had found a brook by the treeline where the stones were smooth and the water clear; ${fname} conjured lather from ${their} pouch to split between them all, and when they had finished and no longer smelled of death and thaum-smoke, she very nearly cries.
        
They spend the night in her tent, for a change of pace—her curled in her cot and them on the packed earth. She gently warns them that the march is long still, and it would not do for them to catch a cold so close to the war's end. Saine answers her concern by rolling her aside and staking his claim on the other side of her cot, Leon and ${fname} following close behind him.
        
She protests and does not mean it. The press of her friends against her is cozy and warm, and through it all she allows herself to imagine the future they are fighting for. For a brief moment, the tent flaps morph into the walls of her home, the air swelling with the scent of her mother's cooking. Under the tangle of limbs and steady breaths, her head hazy with dreams of friendship and of peace, sleep finds her the way it hadn't in years.
*page_break
She tastes blood at the back of her mouth.

She knows then that she's at the edge of mana exhaustion, scraping together what little magical nectar still remains in the pit of her stomach. She feels pain like she hadn't since that fateful day in the Esteram forest, when venom had sunk into her skin, bright blue and deadly, and death was a sparrow already perched on her shoulder.

${fname} had been the one to pull her back out, in the end. And now ${their} form lays broken-still on the solid earth, the flare of her enchantments casting a deathly pallor against ${their} sallowing skin.

*choice
    #$!{they} @{plural look|looks} almost serene, despite it all.
        $!{their} gaze on her is tender and soft in a way that she does not deserve, an advance forgiveness on the failure she is fashioning with her own two hands. She almost tells ${them} to look away, because for all that the act was meant to grant her solace the sting of it prickles against her skin as if it were an accusation leveled.
        
        [i]You did this to me[/i], ${fname} does not say, does not think, though she hears it all the same. [i]My blood is on your hands.[/i]
        
        "Thank you for everything," ${they} @{plural say|says} instead, when ${their} consciousness has all but slipped away. "Please know that I regret nothing."
        
        "Don't," she replies, and though her voice comes out just the shadow of a whisper, she knows ${they} @{plural hear|hears} her loud and clear. "Don't you dare die on me."
        
        ${fname} replies with a smile that told her nothing and everything within the breadth of a second, ${their} eyes fluttering to a close. Slow and final in a way that makes her fear they would stay that way forever.
        
        She finds a strength then that had been pooling somewhere in the cavity of her chest, between the lungs that had lost its air and the heart that beats hard and quick, and discovers that when confronted by her worst nightmares, she is far stronger than she gives herself credit for.
    #$!{they} @{plural are|is} too weak for words, but the terror in ${their} eyes is impossible to mistake.
        It flickers there like a dying light, the dance of a candle at the base of its wick. She hangs on to that fear with desperate fervor, for she knows that when it fades ${fname} too will fade with it.
        
        [i]You did this to me,[/i] ${fname} does not say, does not think, though she hears it all the same. [i]You did this to me, so you had better save me now.[/i]
        
        "I don't want to die," ${they} @{plural say|says} instead, when ${their} consciousness has all but slipped away.
        
        "You won't," she replies, and the promise hangs feather-light in the air without the burden of truth to weigh it down. Her voice is iron-strong despite it all, bolstered by conviction she did not truly possess. "You'll make it through this, ${fname}. I'll see to it that you do."
        
        $!{they} @{plural look|looks} up at her through dark, hooded eyes, and the tempest there calms when ${they} @{plural make|makes} the choice to trust her. It remains there for a moment until ${their} eyes flutter to a close—slow and final in a way that makes her fear they would stay that way forever.
        
        She finds a strength then that had been pooling somewhere in the cavity of her chest, between the lungs that had lost its air and the heart that beats hard and quick, and discovers that when confronted by her worst nightmares, she is far stronger than she gives herself credit for.
    #$!{they} @{plural meet|meets} ${their} fate with quiet resignation.
        $!{they} @{plural wear|wears} sorrow in ${their} eyes that speaks of practiced fortitude, as if death were the still sea at the end of the brook, and ${they} the water that flows there, steady as time. She feels ${them} wet-slick between the gaps of her fingers, curls them as if a fist would hold water any better than an open palm.
        
        [i]You did this to me,[/i] ${fname} does not say, does not think, though she hears it all the same. [i]You were the ones to wage the war, and yet I'm the one who has to pay the price.[/i]
        
        "So this is how it ends," ${they} @{plural say|says} instead, when ${their} consciousness has all but slipped away. "What a sorry sight I must make."
        
        "Don't say that," she replies, though there is no bite behind the rebuke. Still her voice is steady and iron-strong, as if she might barter mere conviction for the boon of ${their} life. "You'll make it through this, ${fname}. I'll see to it that you do."
        
        $!{they} @{plural look|looks} up at her through dark, hooded eyes, lets flourish a smile that carries the grace of a parting gift. When ${their} eyes finally flutter to a close the motion is languid and final, in a way that makes her fear they would stay that way forever.
        
        She finds a strength then that had been pooling somewhere in the cavity of her chest, between the lungs that had lost its air and the heart that beats hard and quick, and discovers that when confronted by her worst nightmares, she is far stronger than she gives herself credit for.
*page_break
${fname} lives to die thrice more, and each time she is tempted to grant ${them} the mercy of peace, the kind that need not be paid for in victory. Then she pictures the hearth that would warm three instead of four, a cot lighter for ${their} absence but heavier for the load of their hearts.

The image strikes a chill against her spine and bleeds the spell from her fingers, and before she could catch herself she is casting like a woman possessed.
*page_break
There had been no time to mourn the saintess, in the end.

She had felt the shame of the slight settle in her chest, white-hot and scalding, but thought lucidly that for all that her mentor carried the air of divinity, she too was a woman of the world. She would understand, surely, that her grief must be withheld, if only so that hers is the only grave she would need to visit this year.
*page_break
She tries and it comes to nothing. Leon declares that ${fname} is to burn, and it is only then that she understands the gentle luxury a simple grave would provide.
*page_break
She takes a tonic on the morning of the pyre, feels the heart hammering in her chest soften into a beat low and hushed. The gentle specter of sleep hangs over her before the panic could wrench itself awake, and she allows herself to peer through her lids one last time to behold the city past her windows. She watches the dancing sunbeams and cloudless skies, and drowsily thinks that if nothing else, it is a beautiful day to die.

She startles awake when the sun is high in the sky, high enough for her to know that the deed has been done. Naively she had thought that only numbness awaited her on the other side. A cold cognizance that would let her pick herself up from the mattress and amble to the site of the pyre, to behold what remains of the @{pronvar man|woman|mage} she had not the strength to watch burn.

Instead she feels something catch in her throat, scratchy and harsh, and it is then that sorrow pours out of her without measure. She calls for her father's squire and he comes running; somehow she finds the air she needs to put her request to words, and somehow he understands her even through the slur of her lament.

He returns late in the evening and presents her with a patch of linen, texture harsh as a grain sack and soot-black at its edges. Intuition tells her it is all ${they} had left behind and soon the squire tells her that too. She presses the cloth firmly against her chest, feels the storm there swell and bloat and build, and wonders what it says about her that fabric dwarfed by her palm is all that keeps her from drowning.
*page_break
She departs for the cathedral at the turn of the month, and they proclaim her saintess even before the first day is out. Her robes are satin and the finest silk, her circlet crafted by imperials and made holy by the blood of her predecessors. All of it chafes against her skin, but she bears the dishonor with a smile. Swears her faith to the church that had called for ${their} burning.

(In her quarters that night, alone under the gentle beams of the dying moon, she cannot help but to wonder if there is anything left within her to hollow out.)
*page_break
[i]…your witchroot has grown to a splendid size, daughter. Callum waters it every day, like you told him to, and he says he'd love for you to come down to the manor and see. If you can make the time, of course—I know the Church must come first. But it would be nice to have you here for Firia's birthday.[/i]

[i]Ah, we also found a strange tome in your room just the other day. Callum is the only one who could read the letters, and he swore it was a tome of necromancy, the silly boy. We've kept it somewhere he can't reach, but I fear the boy has gone into a tantrum since. I would ask for your permission to burn it all the same, daughter, if only to buy him peace of mind…[/i]

She crumples up the letter and tosses it into the fireplace, resisting the curse already dancing on the tip of her tongue. She reaches for her quill and a piece of clean parchment, and writes back:

[i]We cannot erase that which we do not understand, mother. Callum is correct, and yet I must ask you to keep it still—[/i]

She heaves a sigh, then, and after a moment of consideration that too she feeds to the flames. What would ${fname} say if ${they} saw her now? A desperate child grasping at straws. Attempting to right a wrong she had been too powerless to stop.

[i]It is a tome of small importance, mother[/i], she ends up writing back. [i]Let Callum burn it himself, if he fears it so. And I will come down in a week, as you ask. It has been too long since I last made it home.[/i]
*page_break
*set exonerate true
The breath leaves her lungs when the tome finally cracks open.

She weeps what sobs she can muster even as she reaches for her quill. Puts truth to paper even as tears blot the ink.
*page_break
"I'm sorry to ask this of you."

Saine refuses to meet her gaze even as the words tumble from his mouth. He had been so pliant and mindful of her since the day of the pyre, as if she were shards of glass scattered on the cold floor. She feels her teeth set at the thought of cracks in her facade, that this grieving boy who is not yet twenty might show her pity she did not dare show herself.

He fidgets in his place, stance faltering as he considers the kindness of leaving her be. Gentle, thoughtful hesitance. A hand clasping the tattered brown cloak he could not have worn for protection.

His other palm remains open, expectant of the solace-cloth he means to deliver to East Param.

[i]Too much[/i], ${fname} says from where ${they} @{plural float|floats} beside her. [i]He asks too much of you.[/i]

[i]He does[/i], rings another voice, warm and high and she recognizes it as her own. [i]Don't give it away.[/i]

[i]Don't give me away.[/i]

Saine shifts awkwardly where he stands, lets his fingers curl to a close. She snatches his hand before he retreats, slips the patch of linen onto his palm, and retracts her own so that it does not change its mind.

([i]betrayer[/i], ${fname} jeers through lips of pale blue, cracks like crows' feet on the ghast-skin around ${their} eyes, she feels the cut of the shards deep in her chest, and ${fname} is relentless as ${they} @{plural breathe|breathes} and @{plural repeat|repeats}, [i]betrayer, betrayer, ah[/i])

She closes the door before Saine could catch her crumple, ignores the gentle raps on wood and muffled concern beyond the jambs. There at the foot of the door, her sight distorted by tears she could not feel fall, she sees the ghost linger like ${they} might stay there for years.
*page_break
This is the end of [i]Betrayer.[/i] Thank you for playing!
